Необходимо выполнить итерацию хеша, полученного из запроса MySQL

Если переменная содержит ссылку, вам необходимо разыменовать ее, чтобы получить доступ к объекту, на который указывает ссылка.

my $VAR1 = {
    categories => \[
                      [
                        1,
                        'General',
                        './PostList.pl?cat=General'
                      ],
                      [
                        2,
                        'DevOps',
                        './PostList.pl?cat=DevOps'
                      ]
                  ]  # <- this was missing in your code!
};
print ${ $VAR1->{categories} }->[1][1];  # DevOps

$VAR1 — это ссылка на хэш, мы можем разыменовать ее, используя стрелку.

$VAR1->{categories}

Значение, связанное с «категориями», является ссылкой на ссылку на массив, поэтому нам нужно разыменовать его как скаляр, чтобы получить ссылку на массив.

${ $VAR1->{categories} }

тогда мы сможем снова использовать стрелку, чтобы попасть в массив.

${ $VAR1->{categories} }->[1]

Кстати, если $sth->finish(); стоит после return, он никогда не будет выполнен.

Код, который вы показываете для GetCategories(), предназначен для возврата массива ссылок Hashrefs. Обратите внимание на использование пустой хеш-ссылки в качестве аргумента fetchall_arrayref({}), что описано здесь (если $slice является хэш-ссылкой, fetchall_arrayref извлекает каждую строку как хэш-ссылку). Однако остальная часть вашего вопроса показывает структуру, которая не была создана этим кодом. Вот полный пример, демонстрирующий использование fetchall_arrayref({}) и способ доступа к определенному элементу в возвращаемой структуре (извините, это postgres, но здесь это не имеет значения):

use 5.030;
use warnings;
use Data::Dumper;
use DBD::Pg;
my $sql =q|
SELECT * FROM
(VALUES( 1,
        'General',
        './PostList.pl?cat=General'),
       ( 2,
         'DevOps',
         './PostList.pl?cat=DevOps')
)AS categories("CatID", "CatName", "CatLink")|; 


my $dh = DBI->connect(
    "DBI:Pg:dbname=postgres; host=127.0.0.1", "postgres");
die $DBI::errstr unless $dh;
my $sth = $dh->prepare($sql);
$sth->execute();
my $res = $sth->fetchall_arrayref({});

my $vars = {categories => $res};

print Dumper $vars;

#access CatName of 2nd row:

say $vars->{categories}[1]{CatName};

принты:

$VAR1 = {
          'categories' => [
                            {
                              'CatLink' => './PostList.pl?cat=General',
                              'CatName' => 'General',
                              'CatID' => 1
                            },
                            {
                              'CatLink' => './PostList.pl?cat=DevOps',
                              'CatName' => 'DevOps',
                              'CatID' => 2
                            }
                          ]
        };
DevOps

Я попробую это позже.

Я добился того, что мне нужно, следующим образом, но это не идеально. Как только я разберусь со ссылками на Perl и областью видимости переменных, я последую вашему совету, потому что он выглядит более компактным и универсальным, а это то, чего я хочу.

$sth->execute() or die $DBI::errstr;
    my @arrRtn;
    my $i=0;

  while ( my @row = $sth->fetchrow_array ) {
    my ($cat_id, $cat_name, $cat_link ) = @row;
    @arrRtn[$i] = {
        'CatID'  => $cat_id,
        'CatName' => $cat_name,
        'CatLink' => $cat_link,
    };
    $i++;
}
      
$sth->finish();
#print Dumper(@hRtn);
foreach (@arrRtn)
{
    print "ID: $_->{'CatID'}<br>NAME: $_->{'CatName'}<br>LINK: $_->{CatLink}<br><br>";
}