Объединение многострочной пакетной команды со встроенными комментариями

Невозможно иметь такие команды, как rem, внутри команды, распределенной по нескольким строкам. Символ каретки ^ в качестве escape-символа в конце строки работает только при наличии следующего возврата каретки (игнорируется при автоматическом чтении пакетного файла) и перевода строки. Даже конечный пробел, такой как обычный пробел или горизонтальная табуляция, приведет к разделению длинной командной строки на две командные строки, и выполнение исполняемого файла не будет работать должным образом. Командный процессор Windows использует очень старый синтаксис, который не поддерживает пробелы и табуляцию, как современные интерпретаторы сценариев. Дополнительную информацию об обработке командной строки или пакетного файла см. в разделе Как интерпретатор команд Windows (CMD.EXE) анализирует сценарии?

Решение очень простое. Длинная командная строка записывается в пакетном файле как одна длинная командная строка, и все параметры объясняются в блоке выше, который более или менее игнорируется при выполнении с использованием команды goto, как показано ниже.

goto RunExe
rem   -switch1=3 ......... should be 3 or 5, three means xxx and 5 means yyy
rem   -file-format=csv ... output file format, supported are csv and xml
rem   -out=result ........ written file, file extension is copied from file format
:RunExe
executable -switch1=3 -argument1=some-file.txt -file-format=csv

Вы можете использовать процентные комментарии.
Они полностью исчезают с линии, поэтому не мешают.

echo aaa ^%=     My first comment here =%
bbb^%=           Second comment        =%
ccc%=            My last comment       =%

Это работает, потому что парсер пытается расширить комментарий как переменную, но если он не может найти такую ​​переменную, он расширяется до пустой строки.
Поэтому начинать следует с %=, потому что переменные не могут быть созданы с начальным знаком равенства.
Важно не включать в комментарии двоеточия, поскольку они рассматриваются как специальные операторы модификации переменных и полностью нарушают комментарий.

Процентный комментарий можно использовать практически в любой позиции строки.

echo aaa ^%= My comment here =%
bbb%= This comment is in front of the caret=%^
c%=This comment is inside the text =%cc

Ваша первоначальная концепция неверна, потому что символ конца строки ^ должен быть помещен в конец строки...

Я предлагаю другой подход, в котором нет проблем с двоеточиями в комментариях:

@echo off 
setlocal EnableDelayedExpansion

set ^"\n=^
%don't remove%
^"

set "command = "
for /F "delims=/" %%a in (^"

executable                                                                          !\n!
 -switch1^=3               // should be: 3 or 5, three means xxx and 5 means yyy    !\n!
 -argument1^=some-file.txt                                                          !\n!
 -file-format^=csv         // output file format, supported are: csv and xml        !\n!
 -out^=result              // written file, file extension is copied from file format

^") do set "command=!command! %%a"

%command%

В этом методе сначала создается переменная «конец строки» \n и помещается в конец каждой строки, содержащей команду. Каждая строка обрабатывается командой for /F и используется для сборки окончательной команды. «Часть комментария» отделяется косой чертой, которая включена в часть delims=/ команды FOR /F. Вы также можете использовать заглавную букву «R» в качестве разделителя комментариев и разделять комментарии с помощью команды REM.

Выполненная команда такова:

executable   -switch1=3   -argument1=some-file.txt   -file-format=csv   -out=result

Единственным недостатком этого метода является то, что знаки равенства необходимо ^= экранировать, поскольку синтаксический анализатор их удаляет.