Преобразование XSLT: перемещение значений тегов в родительские
не могли бы вы поддержать меня со следующим преобразованием XSLT:
Исходный XML-файл:
<root>
<Invoice>
<ID>
<_>INV12345</_>
</ID>
<InvoiceTypeCode>
<_>01</_>
<listVersionID>1.0</listVersionID>
</InvoiceTypeCode>
<InvoicePeriod>
<StartDate>
<_>2017-11-26</_>
</StartDate>
<EndDate>
<_>2017-11-30</_>
</EndDate>
</InvoicePeriod>
<AccountingSupplierParty>
<AdditionalAccountID>
<_>id-1234</_>
<schemeAgencyName>name1</schemeAgencyName>
</AdditionalAccountID>
</AccountingSupplierParty>
</Invoice>
</root>
Итоговый XML-файл:
<Invoice>
<ID>NV12345</ID>
<InvoiceTypeCode listVersionID = "1.0">01</InvoiceTypeCode>
<InvoicePeriod>
<StartDate>2017-11-26</StartDate>
<EndDate>2017-11-30</EndDate>
</InvoicePeriod>
<AccountingSupplierParty schemeAgencyName = "name1">
<AdditionalAccountID>id-1234</AdditionalAccountID>
</AccountingSupplierParty>
</Invoice>
Необходимо сделать:
- удалить корневой тег;
- удалить все теги <_>, но их значения переместятся в родительские теги;
- все остальные теги, кроме тегов <_>, перемещаются как атрибуты своих родительских тегов.
Такая задача возникла при преобразовании Джексоном UBL (Universal Business Language) из JSON в XML.
Я только что нашел, как удалить корневой тег:
<xsl:stylesheet version = "1.0" xmlns:xsl = "http://www.w3.org/1999/XSL/Transform">
<!-- identity template -->
<xsl:template match = "node() | @*">
<xsl:copy>
<xsl:apply-templates select = "node() | @*" />
</xsl:copy>
</xsl:template>
<!-- remove root tag -->
<xsl:template match = "/*">
<xsl:apply-templates select = "node()" />
</xsl:template>
</xsl:stylesheet>
Да, это моя ошибка, спасибо, @michael.hor257k
Ответы 2
Вы сформулировали три правила, и все они могут быть выражены в виде шаблонных правил.
Начните с шаблона удостоверения, в версии 3.0 это `<xsl:mode on-no-match="shallow-copy"/>; в более ранних версиях это нужно было указывать явно, но я вижу, что вы это сделали.
Вы также выполнили первое правило для удаления корневого элемента.
Следующий:
- удалить все теги <_>, но их значения переместятся в родительские теги;
Это точно так же, как удаление корневого элемента:
<xsl:template match = "_"><xsl:apply-templates/></xsl:template>
(вам не нужно явно перемещать значения в родительский элемент, это произойдет автоматически).
Окончательно:
- все остальные теги, кроме тегов <_>, перемещаются как атрибуты своих родительских тегов.
Я предполагаю (из вашего примера), что под «всеми остальными» вы подразумеваете все элементы, имеющие только текстовый контент. Это требует некоторого изменения порядка, поэтому правило необходимо применить на следующем уровне. Удобный трюк здесь — сортировка дочерних элементов по логическому условию (сортировка false перед истиной):
<xsl:template match = "*">
<xsl:copy>
<xsl:apply-templates>
<xsl:sort select = "boolean(child::*)"/>
</xsl:apply-templates>
</xsl:copy>
</xsl:template>
<xsl:template match = "*[not(child::*)]">
<xsl:attribute name = "{name()}" select = "."/>
</xsl:template>
или если вы все еще используете версию 1.0,
<xsl:template match = "*[not(child::*)]">
<xsl:attribute name = "{name()}">
<xsl:value-of select = "."/>
</xsl:attribute>
</xsl:template>
Спасибо @MichaelKay за ответ. Первое преобразование работает отлично. Второй не компилируется: «Неожиданный атрибут 'select' со значением'». Третий выдает ошибку: «Невозможно добавить атрибут ''='INV12345' к элементу 'ID'»_
Я считаю, что получаю ожидаемый результат, используя эту таблицу стилей XSLT 1.0:
<xsl:stylesheet version = "1.0" xmlns:xsl = "http://www.w3.org/1999/XSL/Transform">
<xsl:output method = "xml" indent = "yes"/>
<xsl:strip-space elements = "*"/>
<xsl:template match = "*">
<xsl:copy>
<xsl:copy-of select = "@*"/>
<!-- convert leaf child elements (except _) to attributes -->
<xsl:for-each select = "*[not(* or self::_)]">
<xsl:attribute name = "{name()}">
<xsl:value-of select = "."/>
</xsl:attribute>
</xsl:for-each>
<!-- process other child elements and text nodes -->
<xsl:apply-templates select = "*[*] | _ | text() "/>
</xsl:copy>
</xsl:template>
<!-- remove root and _ elements -->
<xsl:template match = "/* | _">
<xsl:apply-templates/>
</xsl:template>
</xsl:stylesheet>
Но при этом не обрабатываются комментарии и инструкции по обработке.
Имейте в виду, что удаление корневого элемента может привести к тому, что результат станет фрагментом XML, а не корректным XML-документом.
Я вижу разницу между вашим результатом и тем, который ожидал ОП. Но, похоже, это потому, что вы следовали установленным правилам ФП - см. Мой комментарий к вопросу.
Спасибо, @y.arazim, кажется, все работает отлично. И за замечания спасибо: мне не нужно обрабатывать комментарии и инструкции. И я уверен, что после удаления корневого тега я получу правильно сформированный XML-файл.
Только если вы можете быть уверены, что корневой элемент имеет только один дочерний узел.
Результат, который вы показываете, не соответствует вашим собственным правилам: элемент
schemeAgencyNameявляется дочерним элементомAdditionalAccountID, но вы превратили его в атрибут его прародителяAccountingSupplierParty.