Набор ресурсов всегда включал это. По крайней мере, с Windows 2000.

Кроме того, в пакете Cygwin есть sleep - вставьте его в ваш PATH и включите cygwin.dll (или как там он называется) и путь к делу!

SLEEP.exe входит в состав большинства наборов ресурсов, например Комплект ресурсов Windows Server 2003, который также можно установить в Windows XP.

Usage:  sleep      time-to-sleep-in-seconds
        sleep [-m] time-to-sleep-in-milliseconds
        sleep [-c] commited-memory ratio (1%-100%)

У меня возникла аналогичная проблема, но я просто создал очень короткое консольное приложение на C++, чтобы сделать то же самое. Просто запустите MySleep.exe 1000 - возможно, это проще, чем загрузка / установка всего набора ресурсов.

#include <tchar.h>
#include <stdio.h>
#include "Windows.h"

int _tmain(int argc, _TCHAR* argv[])
{
    if (argc == 2)
    {
        _tprintf(_T("Sleeping for %s ms\n"), argv[1]);
        Sleep(_tstoi(argv[1]));
    }
    else
    {
        _tprintf(_T("Wrong number of arguments.\n"));
    }
    return 0;
}

Использование пинг хорошо, если вы просто хотите «немного подождать». Это связано с тем, что вы зависите от других функций внизу, таких как работа вашей сети и тот факт, что на 127.0.0.1 ничего не отвечает. ;-) Может и не получится, но не невозможно ...

Если вы хотите быть уверены, что ждете точно в указанное время, вам следует использовать функциональность sleep (которая также имеет то преимущество, что не использует мощность процессора или не дожидается готовности сети).

Найти уже готовый исполняемый файл для сна - самый удобный способ. Просто поместите его в папку Windows или в любую другую часть стандартного пути, и он всегда доступен.

В противном случае, если у вас есть среда компиляции, вы легко можете ее создать самостоятельно. Функция Sleep доступна в kernel32.dll, поэтому вам просто нужно ее использовать. :-) Для VB / VBA объявите следующее в начале вашего источника, чтобы объявить функцию сна:

private Declare Sub Sleep Lib "kernel32" Alias "Sleep" (byval dwMilliseconds as Long)

Для C#:

[DllImport("kernel32.dll")]
static extern void Sleep(uint dwMilliseconds);

Вы найдете здесь больше об этой функциональности (доступной с Windows 2000) в Функция сна (MSDN).

В стандарте C sleep() включен в стандартную библиотеку, а в Visual Studio C от Microsoft функция называется Sleep(), если мне не изменяет память. ;-) Эти двое принимают аргумент в секундах, а не в миллисекундах, как в двух предыдущих объявлениях.

ОБНОВИТЬ

Команда timeout, доступная в Windows Vista и более поздних версиях, должна быть используемой командой, как описано в другом отвечать к этому вопросу. Далее следует ответ Старый.

Старый ответ

Если у вас установлен Python или вы не против его установить (у него есть и другие варианты использования :), просто создайте следующий скрипт sleep.py и добавьте его где-нибудь в свой PATH:

import time, sys

time.sleep(float(sys.argv[1]))

Это позволит делать паузы менее секунды (например, 1,5 секунды, 0,1 и т. д.), Если у вас возникнет такая необходимость. Если вы хотите называть его sleep, а не sleep.py, вы можете добавить расширение .PY в переменную среды PATHEXT. В Windows XP вы можете редактировать его в:

Мой компьютер → Свойства (меню) → Дополнительно (вкладка) → Переменные среды (кнопка) → Системные переменные (рамка)

Я использую эту программу сна C#. Возможно, вам будет удобнее, если вы предпочитаете C#:

using System;
using System.Collections.Generic;
using System.Linq;
using System.Text;
using System.Threading;

namespace sleep
{
    class Program
    {
        static void Main(string[] args)
        {
            if (args.Length == 1)
            {
                double time = Double.Parse(args[0]);
                Thread.Sleep((int)(time*1000));
            }
            else
            {
                Console.WriteLine("Usage: sleep <seconds>\nExample: sleep 10");
            }
        }
    }
}

Еще более легким, чем решение Python, является Perl один лайнер.

Чтобы засыпать на семь секунд, введите это в сценарий BAT:

perl -e "sleep 7"

Это решение обеспечивает разрешение только в одну секунду.

Если вам нужно более высокое разрешение, используйте Time :: HiRes. модуль из CPAN. Он обеспечивает usleep(), который спит в микросекунды и nanosleep(), который спит в наносекундах (обе функции принимают только целочисленные аргументы). Увидеть Stack Overflow вопрос Как мне поспать миллисекунду в Perl? для получения дополнительной информации.

Я использую ActivePerl много лет. Очень легко установить.

Вы можете использовать ping:

ping 127.0.0.1 -n 11 -w 1000 >nul: 2>nul:

Подождет 10 секунд.

Причина, по которой вы должны использовать 11, заключается в том, что первый пинг выключается сразу, а не через одну секунду. Число всегда должно быть на единицу больше, чем количество секунд, которое вы хотите подождать.

Имейте в виду, что цель -w - не ждать ни секунды. Это необходимо для того, чтобы вы не ждали более более одной секунды в случае возникновения сетевых проблем. ping сам по себе будет отправлять один пакет ICMP в секунду. Вероятно, это не требуется для localhost, но от старых привычек трудно избавиться.

При сбое сервера, был задан аналогичный вопрос, и решение было:

choice /d y /t 5 > nul

Вы можете использовать слой Windows cscript WSH и этот файл JavaScript wait.js:

if (WScript.Arguments.Count() == 1)
    WScript.Sleep(WScript.Arguments(0)*1000);
else
    WScript.Echo("Usage: cscript wait.js seconds");

Просто поместите это в свой командный файл, где хотите подождать.

@ping 127.0.0.1 -n 11 -w 1000 > null

В зависимости от ваших требований к совместимости используйте ping:

ping -n <numberofseconds+1> localhost >nul 2>&1

например чтобы подождать 5 секунд, используйте

ping -n 6 localhost >nul 2>&1

или в Windows 7 или новее используйте timeout:

timeout 6 >nul

Команда timeout доступна начиная с Windows Vista:

c:\> timeout /?

TIMEOUT [/T] timeout [/NOBREAK]

Description:
    This utility accepts a timeout parameter to wait for the specified
    time period (in seconds) or until any key is pressed. It also
    accepts a parameter to ignore the key press.

Parameter List:
    /T        timeout       Specifies the number of seconds to wait.
                            Valid range is -1 to 99999 seconds.

    /NOBREAK                Ignore key presses and wait specified time.

    /?                      Displays this help message.

NOTE: A timeout value of -1 means to wait indefinitely for a key press.

Examples:
    TIMEOUT /?
    TIMEOUT /T 10
    TIMEOUT /T 300 /NOBREAK
    TIMEOUT /T -1

Примечание: он не работает с перенаправлением ввода - тривиальный пример:

C:\>echo 1 | timeout /t 1 /nobreak
ERROR: Input redirection is not supported, exiting the process immediately.

Я впечатлен этим:

http://www.computerhope.com/batch.htm#02

choice /n /c y /d y /t 5 > NUL

Технически вы говорите команде choice принимать только y. По умолчанию это y, чтобы сделать это за 5 секунд, чтобы не отображать подсказки и вывести все, что он говорит, в NUL (например, нулевой терминал в Linux).

Я не согласен с ответами, которые нашел здесь.

Я использую следующий метод, полностью основанный на возможностях Windows XP для задержки в пакетном файле:

ЗАДЕРЖКА.BAT:

@ECHO OFF
REM DELAY seconds

REM GET ENDING SECOND
FOR /F "TOKENS=1-3 DELIMS=:." %%A IN ("%TIME%") DO SET /A H=%%A, M=1%%B%%100, S=1%%C%%100, ENDING=(H*60+M)*60+S+%1

REM WAIT FOR SUCH A SECOND
:WAIT
FOR /F "TOKENS=1-3 DELIMS=:." %%A IN ("%TIME%") DO SET /A H=%%A, M=1%%B%%100, S=1%%C%%100, CURRENT=(H*60+M)*60+S
IF %CURRENT% LSS %ENDING% GOTO WAIT

Вы также можете вставить день в расчет, чтобы этот метод также работал, когда интервал задержки превышает полночь.

Используя метод ping, как описано, я делаю это, когда не могу (или не хочу) добавлять больше исполняемых файлов или устанавливать какое-либо другое программное обеспечение.

Вы должны пинговать то, чего нет, и использовать флаг -w, чтобы он не работал через это время, а не пинговать что-то, что является там (например, localhost) -n раз. Это позволяет вам обрабатывать время меньше секунды, и я думаю, что это немного точнее.

например

(проверьте, что 1.1.1.1 не используется)

ECHO Waiting 15 seconds

PING 1.1.1.1 -n 1 -w 15000 > NUL
  or
PING -n 15 -w 1000 127.1 >NUL

Или командная строка Python, например, на 6 с половиной секунд:

python -c "import time;time.sleep(6.5)"

В Блокноте напишите:

@echo off
set /a WAITTIME=%1+1
PING 127.0.0.1 -n %WAITTIME% > nul
goto:eof

Теперь сохраните как wait.bat в папке C: \ WINDOWS \ System32, затем всякий раз, когда вы хотите подождать, используйте:

CALL WAIT.bat <whole number of seconds without quotes>

Мне нравится Ответ Аачини. Я добавил к нему, чтобы обрабатывать день, а также разрешил ему обрабатывать сантисекунды (%TIME% выводит H:MM:SS.CC):

:delay
SET DELAYINPUT=%1
SET /A DAYS=DELAYINPUT/8640000
SET /A DELAYINPUT=DELAYINPUT-(DAYS*864000)

::Get ending centisecond (10 milliseconds)
FOR /F "tokens=1-4 delims=:." %%A IN ("%TIME%") DO SET /A H=%%A, M=1%%B%%100, S=1%%C%%100, X=1%%D%%100, ENDING=((H*60+M)*60+S)*100+X+DELAYINPUT
SET /A DAYS=DAYS+ENDING/8640000
SET /A ENDING=ENDING-(DAYS*864000)

::Wait for such a centisecond
:delay_wait
FOR /F "tokens=1-4 delims=:." %%A IN ("%TIME%") DO SET /A H=%%A, M=1%%B%%100, S=1%%C%%100, X=1%%D%%100, CURRENT=((H*60+M)*60+S)*100+X
IF DEFINED LASTCURRENT IF %CURRENT% LSS %LASTCURRENT% SET /A DAYS=DAYS-1
SET LASTCURRENT=%CURRENT%
IF %CURRENT% LSS %ENDING% GOTO delay_wait
IF %DAYS% GTR 0 GOTO delay_wait
GOTO :EOF

Если в вашей системе есть PowerShell, вы можете просто выполнить эту команду:

powershell -command "Start-Sleep -s 1"

Обновлено: из мой ответ в аналогичной теме люди подняли проблему, из-за которой время, необходимое Powershell для запуска, значительно по сравнению с тем, как долго вы пытаетесь ждать. Если важна точность времени ожидания (т. Е. Дополнительная задержка на секунду или две недопустима), вы можете использовать этот подход:

powershell -command "$sleepUntil = [DateTime]::Parse('%date% %time%').AddSeconds(5); $sleepDuration = $sleepUntil.Subtract((get-date)).TotalMilliseconds; start-sleep -m $sleepDuration"

Это занимает время, когда была введена команда Windows, и сценарий PowerShell отключается до 5 секунд после этого времени. Таким образом, если для запуска powershell требуется меньше времени, чем продолжительность вашего сна, этот подход будет работать (на моей машине это около 600 мс).

Вы можете пофантазировать, поместив сообщение ПАУЗА в строку заголовка:

@ECHO off
SET TITLETEXT=Sleep
TITLE %TITLETEXT%
CALL :sleep 5
GOTO :END
:: Function Section
:sleep ARG
ECHO Pausing...
FOR /l %%a in (%~1,-1,1) DO (TITLE Script %TITLETEXT% -- time left^
 %%as&PING.exe -n 2 -w 1000 127.1>NUL)
EXIT /B 0
:: End of script
:END
pause
::this is EOF

Начиная с Windows Vista, у вас есть команды ТАЙМ-АУТ и СПАТЬ, но чтобы использовать их в Windows XP или Windows Server 2003, вам понадобится Набор инструментов ресурсов Windows Server 2003.

Здесь у вас есть хороший обзор альтернатив сна (метод ping является наиболее популярным, поскольку он будет работать на каждой машине Windows), но есть (по крайней мере) не упомянутый (ab), который использует команду W32TM (Time Service):

w32tm /stripchart /computer:localhost /period:1 /dataonly /samples:N  >nul 2>&1

Где вы должны заменить N на секунды, в которых вы хотите сделать паузу. Кроме того, он будет работать в любой системе Windows без предварительных требований.

Typeperf также можно использовать:

typeperf "\System\Processor Queue Length" -si N -sc 1 >nul

С mshta и javascript (можно использовать для сна менее секунды):

start "" /wait /min /realtime mshta "javascript:setTimeout(function(){close();},5000)"

Это должно быть еще более точным (для ожидания менее секунды) - самокомпилируемый исполняемый файл, основанный на .net:

@if (@X)==(@Y) @end /* JScript comment
@echo off
setlocal
::del %~n0.exe /q /f
::
:: For precision better call this like
:: call waitMS 500
:: in order to skip compilation in case there's already built .exe
:: as without pointed extension first the .exe will be called due to the ordering in PATEXT variable
::
::
for /f "tokens=* delims = " %%v in ('dir /b /s /a:-d  /o:-n "%SystemRoot%\Microsoft.NET\Framework\*jsc.exe"') do (
   set "jsc=%%v"
)

if not exist "%~n0.exe" (
    "%jsc%" /nologo /w:0 /out:"%~n0.exe" "%~dpsfnx0"
)


%~n0.exe %*

endlocal & exit /b %errorlevel%


*/


import System;
import System.Threading;

var arguments:String[] = Environment.GetCommandLineArgs();
function printHelp(){
    Console.WriteLine(arguments[0]+" N");
    Console.WriteLine(" N - milliseconds to wait");
    Environment.Exit(0);    
}

if (arguments.length<2){
    printHelp();
}

try{
    var wait:Int32=Int32.Parse(arguments[1]);
    System.Threading.Thread.Sleep(wait);
}catch(err){
    Console.WriteLine('Invalid Number passed');
    Environment.Exit(1);
}

Вы также можете использовать файл .vbs для определенных тайм-аутов:

Приведенный ниже код создает файл .vbs. Поместите это в верхней части кода rbatch:

echo WScript.sleep WScript.Arguments(0) >"%cd%\sleeper.vbs"

Приведенный ниже код открывает .vbs и указывает, как долго ждать:

start /WAIT "" "%cd%\sleeper.vbs" "1000"

В приведенном выше коде «1000» - это значение временной задержки для отправки в файл .vbs в миллисекундах, например, 1000 ms = 1 s. Вы можете изменить эту часть на любую длину.

Приведенный ниже код удаляет файл .vbs после того, как вы закончите с ним. Поместите это в конец вашего командного файла:

del /f /q "%cd%\sleeper.vbs"

А вот весь код, поэтому его легко скопировать:

echo WScript.sleep WScript.Arguments(0) >"%cd%\sleeper.vbs"
start /WAIT "" "%cd%\sleeper.vbs" "1000"
del /f /q "%cd%\sleeper.vbs"

Это было протестировано на Windows XP SP3 и Windows 7 и использует CScript. Я поставил некоторые меры предосторожности, чтобы избежать подсказок del "". (/q был бы опасен)

Подождите одну секунду:

sleepOrDelayExecution 1000

Подождите 500 мс, а затем выполните следующие действия:

sleepOrDelayExecution 500 dir \ /s

sleepOrDelayExecution.bat:

@echo off
if "%1" == "" goto end
if NOT %1 GTR 0 goto end
setlocal
set sleepfn = "%temp%\sleep%random%.vbs"
echo WScript.Sleep(%1) >%sleepfn%
if NOT %sleepfn% == "" if NOT EXIST %sleepfn% goto end
cscript %sleepfn% >nul
if NOT %sleepfn% == "" if EXIST %sleepfn% del %sleepfn%
for /f "usebackq tokens=1*" %%i in (`echo %*`) DO @ set params=%%j
%params%
:end

Лучшее решение, которое должно работать во всех версиях Windows после Windows 2000:

timeout numbersofseconds /nobreak > nul

Есть лучший способ заснуть с помощью команды ping. Вы захотите проверить связь с несуществующим адресом, поэтому вы можете указать тайм-аут с точностью до миллисекунды. К счастью, такой адрес определен в стандарте (RFC 3330), и это 192.0.2.x. Это не выдумка, это действительно адрес с единственной целью - не существовать. Чтобы было понятно, это применимо даже в локальных сетях.

192.0.2.0/24 - This block is assigned as "TEST-NET" for use in documentation and example code. It is often used in conjunction with domain names example.com or example.net in vendor and protocol documentation. Addresses within this block should not appear on the public Internet.

Чтобы засыпать на 123 миллисекунды, используйте ping 192.0.2.1 -n 1 -w 123 >nul

Обновление: согласно комментариям, есть также 127.255.255.255.

timeout /t <seconds> <options>

Например, чтобы сценарий выполнял непрерывное двухсекундное ожидание:

timeout /t 2 /nobreak >NUL

Это означает, что скрипт подождет 2 секунды, прежде чем продолжить.

По умолчанию нажатие клавиши прерывает тайм-аут, поэтому используйте переключатель /nobreak, если вы не хотите, чтобы пользователь мог прерывать (отменять) ожидание. Кроме того, тайм-аут будет предоставлять посекундные уведомления, чтобы уведомить пользователя о том, сколько времени осталось ждать; это можно удалить, передав команду по конвейеру NUL.

редактировать: Как @martineauуказывает в комментариях, команда timeout доступна только в Windows 7 и выше. Кроме того, команда ping использует меньше процессорного времени, чем timeout. Я все еще верю в использование timeout там, где это возможно, поскольку он более читабелен, чем «взлом» ping. Узнать больше здесь.

ping -n X 127.0.0.1 > nul

Замените X на количество секунд + 1.

Например, если вы подождите 10 секунд, замените X на 11. Чтобы подождать 5 секунд, используйте 6.

Прочтите предыдущие ответы за миллисекунды.

Pathping.exe может спать меньше секунды.

@echo off
setlocal EnableDelayedExpansion 
echo !TIME! & pathping localhost -n -q 1 -p %~1 2>&1 > nul & echo !TIME!

.

> sleep 10
17:01:33,57
17:01:33,60

> sleep 20
17:03:56,54
17:03:56,58

> sleep 50
17:04:30,80
17:04:30,87

> sleep 100
17:07:06,12
17:07:06,25

> sleep 200
17:07:08,42
17:07:08,64

> sleep 500
17:07:11,05
17:07:11,57

> sleep 800
17:07:18,98
17:07:19,81

> sleep 1000
17:07:22,61
17:07:23,62

> sleep 1500
17:07:27,55
17:07:29,06

Поскольку другие предлагают сторонние программы (Python, Perl, пользовательское приложение и т. д.), Другим вариантом является GNU CoreUtils для Windows, доступный по адресу http://gnuwin32.sourceforge.net/packages/coreutils.htm.

2 варианта развертывания:

1. Установите полный пакет (который будет включать полный набор CoreUtils, зависимости, документацию и т. д.).
2. Установите только двоичный файл "sleep.exe" и необходимые зависимости (для получения зависимостей воспользуйтесь зависимостью .exe).

Одним из преимуществ развертывания CoreUtils является то, что вы дополнительно получите множество других программ, которые полезны для написания сценариев (пакет Windows оставляет желать лучшего).

Просто для удовольствия, если у вас установлен Node.js, вы можете использовать

node -e 'setTimeout(a => a, 5000)'

спать на 5 секунд. Он работает на Mac с Node v12.14.0.

Есть много способов выполнить 'спать' в cmd / batch:

Мой любимый:

TIMEOUT /NOBREAK 5 >NUL 2>NUL

Это остановит консоль на 5 секунд без какого-либо вывода.

Наиболее используемое:

ping localhost -n 5 >NUL 2>NUL

Это будет пытаться установить соединение с localhost 5 раз. Поскольку он размещен на вашем компьютере, он всегда будет достигать хоста, поэтому каждую секунду он будет пробовать новый каждую секунду. Флаг -n указывает, сколько раз сценарий будет пытаться установить соединение. В данном случае это 5, так что это будет длиться 5 секунд.

Варианты последнего:

ping 1.1.1.1 -n 5 >nul

В этом скрипте есть некоторые отличия по сравнению с предыдущим. Это не будет пытаться вызвать localhost. Вместо этого он попытается подключиться к 1.1.1.1, очень быстрому веб-сайту. Действие продлится 5 секунд только при наличии активного подключения к Интернету. В противном случае его хватит примерно на 15, чтобы завершить действие.. Не рекомендую использовать этот метод.

ping 127.0.0.1 -n 5 >nul

Это в точности то же, что и в примере 2 (наиболее часто используемом). Также вы можете использовать:

ping [::1] -n 5 >nul

Вместо этого используется версия IPv6 localhost.

Есть много способов выполнить это действие. Однако я предпочитаю метод 1 для Windows Vista и более поздних версий и наиболее часто используемый метод (метод 2) для более ранних версий ОС.