VB.NET Преобразование 4 байтов в целое число

Поскольку вы также изначально пометили теги C# (до того, как теги были отредактированы), вот решение на C# (которое, я предполагаю, вы можете легко преобразовать в VB.NET).

Использование BitConverter, о котором вы упомянули, действительно является правильным решением.

Следующий пример основан на документации MS: Как преобразовать массив байтов в int:

byte[] bytes = new byte[] { 64, 0, 0, 0 };

// If the system architecture is little-endian (that is, little end first),
// reverse the byte array.
if (BitConverter.IsLittleEndian)
    Array.Reverse(bytes);

int i = BitConverter.ToInt32(bytes, 0);
Console.WriteLine("int: {0}", i);

Выход:

int: 1073741824

Обратите внимание на правильную обработку Endianness, чтобы убедиться, что байты обрабатываются в правильном порядке.

Live demo

В ВБ,

    Dim i As Integer
    Dim byts() As Byte = {1, 2, 3, 255}
    If BitConverter.IsLittleEndian Then
        Array.Reverse(byts)
        i = BitConverter.ToInt32(byts, 0) ' i = 16909311
    Else
        i = BitConverter.ToInt32(byts, 0) ' i = -16580095
    End If

Надеюсь, это поможет.

Другой подход...

    Dim byts() As Byte = {1, 2, 3, 255}
    If Not BitConverter.IsLittleEndian Then
        Array.Reverse(byts)
    End If
    Dim i As Integer = 0
    For Each b As Byte In byts
        i = i << 8
        i = i Or b
    Next

Когда элементы mybyte имеют тип Byte, выполнение mybyte(0)) << 24 приводит к созданию Byte, что нехорошо, поскольку все биты теряются. Этот оператор дает результат того же типа, что и левый операнд.

Вам нужно преобразовать каждый элемент в тот тип, который вы хотите получить в конце:

Dim a = CUInt(mybyte(0)) << 24 Or CUInt(mybyte(1)) << 16 Or CUInt(mybyte(2) << 8) Or mybyte(3)

(Арифметический битовый сдвиг имеет более высокий приоритет, чем побитовые операторы. Последний байт не нужно преобразовывать в другой тип.)

Была некоторая несогласованность в вопросе о том, нужно ли целое число или целое число без знака: измените вхождение CUInt на CInt, если первое.

Если вы используете операторы * и +, вы можете сделать

Dim b = (((mybyte(0) * 256 + mybyte(1)) * 256) + mybyte(2)) * 256 + mybyte(3)

или

Dim c = mybyte(0) * 16777216 + mybyte(1) * 65536 + mybyte(2) * 256 + mybyte(3)

которые работают без преобразований, поскольку множители 16777216, 65536 и 256 имеют тип Integer.

Или вы можете просто использовать:

Dim n = BitConverter.ToInt32(mybyte.Reverse().ToArray(), 0)

Наконец, если вы используете .NET Core 2.1 или новее, это очень просто:

Dim d = BinaryPrimitives.ReadInt32BigEndian(mybyte)

Документы: Класс BinaryPrimitives «Используйте эти помощники, когда вам нужно прочитать конкретный порядок байтов».