Десятичный -> Шестнадцатеричный -> Кодировка символов в XSLT

Некоторые из этих кодов находятся за пределами диапазона ASCII, но если под ASCII вы имеете в виду Unicode, вы можете попробовать

<xsl:value-of select = "concat('&amp;#x', hex, ';')"
  disable-output-escaping = "yes"/>

Обновлено: это ответ на исходный вопрос, в котором спрашивалось, как преобразовать шестнадцатеричное число в символ с помощью XSLT.

Я оставляю свой ответ здесь на случай, если он поможет кому-то с этой проблемой, хотя это не очень полезный ответ на вопрос, поскольку впоследствии он был отредактирован.

Вот альтернатива использованию XSLT 2.0, который, как мне кажется, поддерживается IBM DataPower.

XSLT 2.0 включает функцию codepoints-to-string, которая может преобразовать кодовую точку (число) Юникода в строку. Но преобразование шестнадцатеричных цифр в целые числа по-прежнему является трудоемким делом (по крайней мере, я не знаю простого способа сделать это).

<xsl:stylesheet version = "2.0" 
  xmlns:xsl = "http://www.w3.org/1999/XSL/Transform" 
  xmlns:hex = "http://example.com/hex"
  xmlns:xs = "http://www.w3.org/2001/XMLSchema">

  <xsl:output method = "xml" version = "1.1"/>
  
  <xsl:function name = "hex:to-integer" as = "xs:integer">
    <xsl:param name = "hex" as = "xs:string"/>
    <xsl:variable name = "least-significant-digit"
      select = "substring($hex, string-length($hex))"/>
    <xsl:variable name = "most-significant-digits" 
      select = "substring($hex, 1, string-length($hex) - 1)"/>
    <xsl:variable name = "hex-digit-value" select = "
      string-length(
        substring-before('0123456789ABCDEF', $least-significant-digit)
      )
    "/>
    <xsl:choose>
      <xsl:when test = "$most-significant-digits">
        <xsl:sequence 
          select = "$hex-digit-value + 16 * hex:to-integer($most-significant-digits)"/>
      </xsl:when>
      <xsl:otherwise>
        <xsl:sequence select = "$hex-digit-value"/>
      </xsl:otherwise>
    </xsl:choose>
  </xsl:function>
  
  <xsl:template match = "input">
    <output>
      <xsl:apply-templates/>
    </output>
  </xsl:template>
  
  <xsl:template match = "hex">
    <xsl:value-of select = "codepoints-to-string(hex:to-integer(.))"/>
  </xsl:template>
  
</xsl:stylesheet>

Я собираюсь сделать предположение и предположить, что ваши входные значения представляют собой десятичные числа, каждое из которых представляет строку длиной до 4 символов, так что, например, строка "Char" (которая в шестнадцатеричной записи будет представлена ​​как 43 68 61 72) вычисляется как десятичное значение объединенного шестнадцатеричного числа 43686172 = 1130914162.

Теперь, чтобы декодировать такое число обратно в исходную строку, достаточно сделать:

XML

<input>
    <decimal>67</decimal>
    <decimal>17256</decimal>
    <decimal>4417633</decimal>
    <decimal>1130914162</decimal>
    <decimal>100</decimal>
    <decimal>51</decimal>
    <decimal>60</decimal>
</input>

XSLT 2.0

<xsl:stylesheet version = "2.0" 
xmlns:xsl = "http://www.w3.org/1999/XSL/Transform"
xmlns:math = "http://www.w3.org/2005/xpath-functions/math"
exclude-result-prefixes = "math">
<xsl:output method = "xml" version = "1.0" encoding = "UTF-8" indent = "yes"/>

<xsl:template match = "/input">
    <output>
        <xsl:for-each select = "decimal">
            <xsl:variable name = "codes" select = "for $i in 0 to 3 return . idiv math:pow(256, $i) mod 256"/>    
            <charset>
                <xsl:value-of select = "codepoints-to-string(reverse($codes[. > 0]))"/>
            </charset>
        </xsl:for-each>
    </output>
</xsl:template>

</xsl:stylesheet>

Результат

<?xml version = "1.0" encoding = "UTF-8"?>
<output>
   <charset>C</charset>
   <charset>Ch</charset>
   <charset>Cha</charset>
   <charset>Char</charset>
   <charset>d</charset>
   <charset>3</charset>
   <charset>&lt;</charset>
</output>