Как встроить несколько типов параметров в один контейнер типа с ограничением класса?

Короткий ответ

Добавьте параметр типа в AnyData и можете использовать GADT для меньшего количества ограничений в объявлениях экземпляров.

Тип параметра для AnyData

Весь код здесь и ниже работает с GHC версии 8.8.4, также с использованием переключателя компилятора -Wall.

{-# LANGUAGE MultiParamTypeClasses #-}

class OPER a b c where
    add :: a -> b -> c

data AnyData s = DAT s

instance Show s => Show (AnyData s) where
    show (DAT a) = "DAT " ++ show a

instance (OPER a a a) => OPER (AnyData a) (AnyData a) (AnyData a) where
    add (DAT x1) (DAT x2) = DAT (add x1 x2)

instance OPER Int Int Int where
    add nA nB = nA + nB

main :: IO ()
main = 
    do
        print ( add ( DAT ( 7 :: Int ) ) ( DAT ( 13 :: Int ) ) :: (AnyData Int) )

GADT

{-# LANGUAGE MultiParamTypeClasses #-}
{-# LANGUAGE GADTs #-}

class OPER a b c where
    add :: a -> b -> c

data AnyData s where
    DAT :: (OPER s s s) => s -> AnyData s

instance Show s => Show (AnyData s) where
    show (DAT a) = "DAT " ++ show a

instance OPER (AnyData s) (AnyData s) (AnyData s) where
    add (DAT x1) (DAT x2) = DAT (add x1 x2)

instance OPER Int Int Int where
    add nA nB = nA + nB

main :: IO ()
main = 
    do
        print ( add ( DAT ( 7 :: Int ) ) ( DAT ( 13 :: Int ) ) :: (AnyData Int) )

Преимущество GADT заключается в том, что вам не нужно добавлять ограничение в объявление экземпляра для OPER (AnyData a) (AnyData a) (AnyData a).

Другие испытания

Я нашел еще одну устаревшую альтернативу, использующую ограничение в объявлении типа данных.

Компилятор предупреждает: «-XDatatypeContexts устарел: он был широко признан ошибкой и был удален из языка Haskell».

Кроме того, вам необходимо применить UndecidableInstances, чтобы избежать следующей ошибки:

    • Variable ‘s’ occurs more often
        in the constraint ‘OPER s s s’
        than in the instance head ‘Show (AnyData s)’
      (Use UndecidableInstances to permit this)
    • In the instance declaration for ‘Show (AnyData s)’
   |
17 | instance (OPER s s s, Show s) => Show (AnyData s) where
   |          ^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^

УСТАРЕЛО: ограничение в объявлении типа данных (DatatypeContexts).

{-# LANGUAGE MultiParamTypeClasses #-}
{-# LANGUAGE DatatypeContexts #-}
{-# LANGUAGE UndecidableInstances #-}

module X2
    (
        main
    )
    where

class OPER a b c where
    add :: a -> b -> c

data (OPER s s s, Show s) => AnyData s = DAT s

instance (OPER s s s, Show s) => Show (AnyData s) where
    show (DAT a) = "DAT " ++ show a

instance (OPER s s s, Show s) => OPER (AnyData s) (AnyData s) (AnyData s) where
    add (DAT x1) (DAT x2) = DAT (add x1 x2)

instance OPER Int Int Int where
    add nA nB = nA + nB

main :: IO ()
main = 
    do
        print ( add ( DAT ( 7 :: Int ) ) ( DAT ( 13 :: Int ) ) :: (AnyData Int) )

ПРИМЕЧАНИЕ. При применении добавления вам также необходимо добавить результирующий тип, поскольку компилятор не может сделать вывод (см. последнюю строку кода (AnyData Int)).

Окончательный код?

Это то, чего вы хотели достичь?

{-# LANGUAGE MultiParamTypeClasses #-}
{-# LANGUAGE FlexibleInstances #-}
{-# LANGUAGE GADTs #-}

import qualified Data.Map as Map

class OPER a b c where
    add :: a -> b -> c

data AnyData s where
    DAT :: (OPER s s s) => s -> AnyData s

instance Show s => Show (AnyData s) where
    show (DAT a) = "DAT " ++ show a

instance OPER (AnyData s) (AnyData s) (AnyData s) where
    add (DAT x1) (DAT x2) = DAT (add x1 x2)

instance OPER Int Int Int where
    add nA nB = nA + nB

instance OPER (Map.Map Int (Maybe Double)) (Maybe Double) (Map.Map Int (Maybe Double)) where
  add ma mbdlb = Map.map (\mbi -> add mbi mbdlb ) ma

instance OPER (Maybe Double) (Maybe Double) (Maybe Double) where
  add (Just dA) (Just dB) = Just (dA + dB)
  add Nothing _ = Nothing
  add _ Nothing = Nothing

main :: IO ()
main = 
    do
        print ( add ( DAT ( 7 :: Int ) ) ( DAT ( 13 :: Int ) ) :: (AnyData Int) )
        print (add (Map.fromList [(1,Just 3.4),(2,Just 9.4),(3::Int,Just (9.7::Double)),(4,Just 4.8)]) (Just (9.7::Double)) :: (Map.Map Int (Maybe Double)))

Выход

DAT 20
fromList [(1,Just 13.1),(2,Just 19.1),(3,Just 19.4),(4,Just 14.5)]