Получить текст выбранного кода поля в Microsoft Word с помощью AppleScript

Это очень помогает. Итак, это не готовое решение для вашего вопроса, но я не думаю, что вам это действительно нужно, поскольку вам, вероятно, придется рассказать мне больше о том, как это приложение работает, чем это действительно необходимо. Таким образом, этот сценарий фокусируется на вашем первоначальном вопросе о получении кодов полей/результатов из документа слияния.

Я собрал простую рассылку, состоящую из ярлыков и файла данных с 8 записями, в каждой из которых по 5 полей: {"«Фамилия»», «Название должности», «Компания», «Город»», ««Веб»»}. Последнее является ключевым полем.

По сути, сценарий проходит через документ слияния данных и сначала циклически проходит через его поля, затем веб-поле и, наконец, веб-адреса.

Основываясь на вашем сценарии, я не могу точно определить, что вы делаете с каждым адресом, поэтому он заканчивается, собирая только последнюю часть каждого адреса в списке. Непонятными для меня частями являются pbpastes, коды и весь блок System Events. Эта область нуждается в настройке.

Кстати, вполне вероятно, что вы можете избежать некоторых сценариев оболочки, но я пока не могу сказать, как это сделать. Очевидно, что в сценарии есть некоторые излишества, и его можно было бы доработать, но я думаю, что он демонстрирует, как извлекать необходимую информацию. Взгляните на него и дайте мне знать, какие проблемы требуют решения.

tell application "Microsoft Word"
    set d1 to document "cardo_labels.docx"
    
    set fContents to {} -- list of mergefield
    set fResRange to {} -- list of result range, i.e. field merge data
    repeat with x from 1 to (count of fields of d1)
        set fcs to content of field code of field x of d1 --> " MERGEFIELD LastName "
        set frr to content of result range of field x of d1 --> "Smith"
        if fcs is not " NEXT " then -- ignore «Next Record»
            set end of fContents to fcs
            set end of fResRange to frr
        end if
    end repeat
    --> single record example
    fContents --> {" MERGEFIELD LastName ", " MERGEFIELD JobTitle ", " MERGEFIELD Company ", " MERGEFIELD City ", " MERGEFIELD Web "}
    fResRange --> {"Smith", "President", "Acme Screw & Gear", "Metz", "http://zotero.org/users/1234/items/smith-metz"}
    -- NB when not displaying 'merged data', fResRange will appear thusly: {"«LastName»", "«JobTitle»", "«Company»", "«City»", "«Web»"}
    
    set webList to {}
    repeat with y from 1 to (count of fResRange)
        if item y of fResRange begins with "http://zotero.org/users/" then
            set end of webList to (item y of fResRange)
        end if
    end repeat
    --> {"http://zotero.org/users/1234/items/smith-metz"}
    --> {"http://zotero.org/users/1234/items/smith-metz", "http://zotero.org/users/4222/items/branson-metz", "http://zotero.org/users/3236/items/house-metz", "http://zotero.org/users/3342/items/kurtz-london", "http://zotero.org/users/12345/items/jones-london"}
    
    set urlPiece to {}
    set AppleScript's text item delimiters to "/"
    repeat with z in webList
        set end of urlPiece to last text item of z
    end repeat
    -- contents of z
    --> "http://zotero.org/users/1234/items/smith-metz"
    set AppleScript's text item delimiters to ""

    urlPiece
    --> {"smith-metz"}
    --> {"smith-metz", "jones-saopaolo", "branson-metz", "house-metz", "kurtz-london", "jones-london"}
    
end tell

Благодаря идеям от @Mockman.

В сочетании с выделением, вот способ извлечения текста из выбранного кода поля через AppleScript:

tell application "Microsoft Word"
    tell selection
        set fcs to content of field code of field of text object
    end tell
end tell
fcs