XML в CSV для дочерних узлов

(измененный)

Попробуйте что-то вроде:

<xsl:stylesheet version = "2.0" xmlns:xsl = "http://www.w3.org/1999/XSL/Transform">
<xsl:output method = "text" encoding = "utf-8" />
<xsl:strip-space elements = "*"/>
  
<xsl:param name = "delim" select = "','" />
<xsl:param name = "quote" select = "'&quot;'" />
<xsl:param name = "break" select = "'&#xA;'" />
   
<xsl:template match = "/Root">
    <xsl:apply-templates select = "Records/TrRecords" />
</xsl:template>
   
<xsl:template match = "TrRecords">
    <xsl:apply-templates select = "* except Details"/>
    <xsl:apply-templates select = "Details"/>
    <xsl:if test = "position()!=last()">
        <xsl:value-of select = "$break" />
    </xsl:if>
</xsl:template>
 
<xsl:template match = "Details">
    <xsl:value-of select = "$break" />
    <xsl:apply-templates/>
 </xsl:template>
 
<xsl:template match = "*">
    <xsl:value-of select = "concat($quote, normalize-space(), $quote)" />
    <xsl:if test = "position()!=last()">
        <xsl:value-of select = "$delim" />
    </xsl:if>
</xsl:template>
   
</xsl:stylesheet>

Демо здесь.

Обратите внимание, что это предполагает, что ни одно из значений, переданных на выход, не содержит кавычек.

Основная проблема заключается в том, что в шаблоне, который соответствует TrRecords, вы вызываете apply-templates для обработки всех дочерних элементов TrRecords, включая элементы Details, но затем позже вы снова явно перебираете эти Details элементы.

Вот таблица стилей с 4 шаблонами:

• тот, который соответствует корню и применяет шаблоны к TrRecords,
• тот, который соответствует элементам TrRecords и применяет шаблоны к их дочерним элементам
• тот, который соответствует элементам Details и применяет шаблоны к своим дочерним элементам (обратите внимание: это гарантирует, что элемент Details, найденный внутри элемента TrRecords, обрабатывается как строка вывода, содержащая элементы, которые являются столбцами, а не обрабатывается как сам столбец)
• тот, который соответствует любому другому элементу и выводит его как строку в кавычках

Обратите внимание: шаблон TrRecords добавляет разрыв строки после обработки дочерних элементов, а шаблон Details добавляет разрыв строки перед обработкой дочерних элементов.

Также обратите внимание, что строка $delim вставляется после рендеринга значения столбца, только если есть следующие одноуровневые элементы, кроме Details элементов.

<xsl:stylesheet version = "1.0" xmlns:xsl = "http://www.w3.org/1999/XSL/Transform">
   <xsl:output method = "text" encoding = "utf-8" />
   <xsl:param name = "delim" select = "','" />
   <xsl:param name = "quote" select = "'&quot;'" />
   <xsl:param name = "break" select = "'&#xA;'" />
   
   <xsl:template match = "/">
      <xsl:apply-templates select = "Root/Records/TrRecords" />
   </xsl:template>
   <xsl:template match = "TrRecords">
      <xsl:apply-templates select = "*"/>
      <xsl:value-of select = "$break" />
   </xsl:template>
   <xsl:template match = "Details">
      <xsl:value-of select = "$break" />
      <xsl:apply-templates select = "*"/>
   </xsl:template>
   <xsl:template match = "*">
      <xsl:value-of select = "concat($quote, ., $quote)" />
      <xsl:if test = "following-sibling::*[not(self::Details)]">
         <xsl:value-of select = "$delim" />
      </xsl:if>
   </xsl:template>
</xsl:stylesheet>

Однако лично я, если бы у меня был доступный интерпретатор XSLT 2, я был бы склонен написать это по-другому, используя только один шаблон и более сложное выражение XPath:

<xsl:stylesheet version = "2.0" xmlns:xsl = "http://www.w3.org/1999/XSL/Transform">
   <xsl:output method = "text" encoding = "utf-8" />
   <xsl:param name = "delim" select = "','" />
   <xsl:param name = "quote" select = "'&quot;'" />
   <xsl:param name = "break" select = "'&#xA;'" />
   
   <xsl:template match = "/">
      <xsl:value-of separator = "{$break}" select = "
        for $row in 
          (Root/Records/TrRecords | Root/Records/TrRecords/Details)
        return
          string-join(
            for $col in $row/*[not(self::Details)] return concat($quote, $col, $quote),
            $delim
          )
      "/>
   </xsl:template>
</xsl:stylesheet>