Доступ к модели Qt Quick ListView из вложенных элементов в пользовательском делегате

Мне трудно найти идиоматический способ доступа к модели ListView из ее делегата в QML.

Рассмотрим следующий довольно простой пользовательский делегат, который поддерживает флажок рядом с элементом и отслеживает текущий выбранный элемент в списке. (Для пояснения: выбор флажка и выбор списка независимы.)

Rectangle {
    id: wrapper

    required property int index
    required property string name
    required property bool selected

    width: ListView.view.width
    height: 32
    radius: 3
    color: "transparent"

    Label {
        anchors.left: parent.left
        anchors.right: selectedBox.left
        anchors.verticalCenter: parent.verticalCenter
        anchors.margins: 5
        text: wrapper.name

        MouseArea {
            anchors.fill: parent
            onClicked: wrapper.ListView.view.currentIndex = wrapper.index
        }
    }

    CheckBox {
        id: selectedBox

        anchors.right: parent.right
        anchors.verticalCenter: parent.verticalCenter
        checked: wrapper.selected

        onToggled: wrapper.ListView.view.model.setProperty(wrapper.index, "selected", checked)
    }
}

Это рабочий код, хотя заставить onToggle работать было особенно сложно. В конце концов я нашел эту волшебную ListView.view.model руну для доступа к базовой модели в документации Qt и понял, что могу добавить к ней идентификатор делегата.

Однако это кажется слишком многословным, чтобы быть правильным для задач, для которых были созданы делегаты.

Большинство онлайн-примеров жестко запрограммировали это значение для конкретной модели, что нарушает разделение концепций делегата и модели, и я не хочу идти по этому пути. Я также видел, как используется только model (последний список в связанных документах), но у меня это не работает, даже если я require property ListModel model для этого в делегате.

Итак, вопрос в том, есть ли более простой способ.

Вот пример списка и модели для тестирования делегата:

ListView {
    // ...
    model: myModel
    delegate: myDelegate
    highlight: Rectangle {
        color: "lightsteelblue"
        radius: 5
    }
    focus: true
}

ListModel {
    id: myModel

    ListElement {
        name: "Item 1"
        selected: false
    }

    ListElement {
        name: "Item 2"
        selected: false
    }
}

РЕДАКТИРОВАТЬ. На самом деле есть два хороших решения: короткое и более многословное, но надежное.

Я мог бы отказаться от всех необходимых объявлений свойств и использовать

    Label {
        // ...
        text: name
        // ...
    }

    CheckBox {
        // ...
        checked: selected
        onToggled: selected = checked
    }

Я не смог прийти к этому решению, потому что в моем первоначальном проекте было свойство модели с именем checked, и тогда было непонятно, как этот подход можно применить.

В случае конфликта имен можно создать обязательное свойство model, а затем привязать его к соответствующей строке модели списка:

Rectangle {
    id: wrapper

    required property var model
    // ...

    Label {
        // ...
        text: model.name
        // ...
    }

    CheckBox {
        // ..
        checked: model.selected
        onToggled: model.selected = checked
    }
}

Второй вариант кажется предпочтительнее, поэтому я выберу его.