Как связать необязательное свойство в QML?

Вы могли бы что-то вроде этого. Имейте свойство, которое проверяет, определен ли variation, и если это так, назначьте ему привязку в обработчике Component.onCompleted.

Button {
    id: button
    Layout.alignment: Qt.AlignRight | Qt.AlignTop
    text: "Normal"
    implicitWidth: 100

    property bool __variationAvailable: button.variation !== undefined

    Component.onCompleted: {
        if (button.__variationAvailable)
            button.variation = Qt.binding(function() { return comboBox.currentIndex })
    }
}

В настоящее время я не могу воспроизвести точное состояние, поскольку проблема возникает в Qt Design Studio. Я попробовал удалить определенную переменную (закомментировав ее), чтобы она заработала.

Тем временем @iam_peter предложил метод инициализации свойства внутри Component.onCompleted.
Кроме того, существует альтернативный подход с использованием Binding; когда вам нужно инициализировать компонент в отложенном режиме или при выполнении определенного условия.

Начиная с Qt 6.*, существует три способа использования Binding, но в двух из этих методов переменная должна существовать во время синтаксического анализа, а один проверяется во время выполнения.

В настоящее время я не уверен, как воспроизвести условие, при котором компонент имеет свойство во время анализа, но не во время выполнения.

* Исходя из этого, я считаю, что если Binding { when: button.variation !== undefined; button.variation: comboBox.currentIndex } работает, то Binding { button.variation: comboBox.currentIndex } тоже должно работать.

Ниже приведен код, который я пробовал:

component Button: T.Button {
    // property int variation: 0
    text: "Text " + (this.variation ?? "")
}

Row {   
    Button { 
        // Run-time checking, no Error
        id: button1
        Binding {
            when: Object(button1).hasOwnProperty('variation')
            target: button1; property: 'variation'; value: 1
        }
    }

    Button { 
        // Parse-time checking
        // Error, if `variation` is not defined while parsing the file.
        id: button2
        Binding on variation {
            value: 2
            when: Object(button2).hasOwnProperty('variation')
        }
    }

    Button { 
        // Parse-time checking
        // Error, if `variation` is not defined while parsing the file.
        id: button3
        Binding {
            target: button3; property: 'variation'; value: 3
            when: Object(button3).hasOwnProperty('variation')
        }
    }
}

Вы можете смоделировать привязку, клонировав свойство, а затем отреагировав на событие изменения свойства клона:

QtObject {
    property int v: comboBox.currentIndex
    onVChanged: if ("variation" in button) button.variation = v
}

Вы можете Попробовать онлайн!